Joystick Magazine 2000 September/cd joystick no118 septembre 2000 cd 2.iso/Data/sharewares/Jeux/JACK.ZIP/Lisezmoi.txt

Text File | 1999-10-19 | 37KB | 1,397 lines

Salut α tous,

Voila mon deuxieme jeux, donc maintenant si celui ci vous le trouvez α chier vous pouvez m'ecrire pour m'insulter car cette fois je n'ai plus d'excuse.
Je vous donne egalement le listing car beaucoup de gens m'ont demandΘ quel langage j'utilise.

Si vous voulez plus d'infos allez sur le site : www.divgames.com

Merci aussi α l'auteur de la musique EMELIE qui se trouvait dans le CD de Joy.

StΘphane "BIM" CITTADINO
[e-mail]

PS : DΘsolΘ jΘjΘ de ne pas t'avoir rΘpondu mais ton mail ne marche pas !!!

LISTING :

//******************************************
//**                                      **
//**            BOMB JACK 2000            **
//**                                      **
//**                PAR BIM               **
//**                                      **
//**                                      **
//**         COMMENCE LE 01 AOUT 1999     **
//**                                      **
//**                                      **
//******************************************
//******************************************
// REPERES:
//
// CADRE ROUGE
// Haut Gauche : 492 X 9
// Bas Droit :   635 X 472
// Couleur : 52
//
// PLATEFORMES :
// Gauche : 115
// Droite : 349
// Milieu : 239
//
//*******************************************
PROGRAM BOMBJACK;

GLOBAL
robots=0;

col_bombe;
col_bonus;
col_vie;
col_robot;
col_ballon;

compteur_bombe;
bombe_allume=0;
max_num=0;

compte_bonus=0;
compte_ballon=0;

r_b_a=0;
bonus_fois=1;

force_saut=40;

s_vie;
s_saute;
s_bombe;
s_bonus;
s_trans;
s_mort;
s_ballon;
s_alarme;
s_explo;
c_ballon;
c_alarme;

level=1;
point=0;
vie=3;
record;

id_jack;
id_robot;

fonte1;
fonte2;
fonte3;
fonte4;

mort=false;
destruction=FALSE;
reprise=false;

fond;
option;

LOCAL
vitesse_gravite=0;
au_sol=FALSE;
vitesse=0;

num;
forme;

BEGIN

    fopen("jack.dat","a");
    load("jack.dat",&record);

    set_mode(m640x480);

    load_fpg("progs\jack\jack.fpg");

    s_saute=load_wav("progs\jack\saute.wav",0);
    s_bombe=load_wav("progs\jack\bombe.wav",0);
    s_bonus=load_wav("progs\jack\bonus.wav",0);
    s_trans=load_wav("progs\jack\trans.wav",0);
    s_mort=load_wav("progs\jack\mort.wav",0);
    s_ballon=load_wav("progs\jack\ballon.wav",1);
    s_alarme=load_wav("progs\jack\alarme.wav",1);
    s_explo=load_wav("progs\jack\explo.wav",0);
    s_vie=load_wav("progs\jack\vie.wav",0);

    fonte1=load_fnt("progs\jack\jack.fnt");
    fonte2=load_fnt("progs\jack\fonte2.fnt");
    fonte3=load_fnt("progs\jack\point.fnt");
    fonte4=load_fnt("progs\jack\bonus.fnt");

    menu();
END
PROCESS menu();
PRIVATE
fond_menu;
graphic;
BEGIN

    fond_menu=load_map("progs\jack\menu.map"):
    put_screen(0,fond_menu);
    unload_map(fond_menu);
    fade_on();

    //write(fonte1,320,-6,1,"BOMB JACK 2000");
    //write(fonte2,320,64,1,"Le remake qui tue la mort !!!");
    write(fonte3,310,405,1,"Commencer        Instructions        Quitter");

    xput(0,62,320,420,0,100,4,0);

    mouse.size=150;
    mouse.graph=9;

    option=-1;
    WHILE (option<0)
        mouse.graph++;
        if(mouse.graph>10)
            mouse.graph=9;
        end
        IF (key(_esc)) option=1; END

        IF (key(_space) OR key(_enter)) option=0; END

        IF (mouse.left AND mouse.y>370)

            IF (mouse.x<214)
                sound(s_explo,256,256);
                from graphic=56 to 61;
                    mouse.graph=graphic;
                    FRAME;
                end

            option=0;
            ELSE

                IF (mouse.x>426)
                    sound(s_explo,256,256);
                    from graphic=56 to 61;
                        mouse.graph=graphic;
                        FRAME;
                    end

                    option=1;
                    exit("Tchao !!!",0);
                ELSE
                    sound(s_explo,256,256);
                    from graphic=56 to 61;
                        mouse.graph=graphic;
                        FRAME;
                    end

                    option=2;
                    fade(200,0,0,6);
                    WHILE(fading)
                        frame;
                    end

                END
            END
        END
        FRAME;
    END

    clear_screen();
    delete_text(all_text);
    mouse.graph=0;

    SWITCH(option)
        CASE 0:
            control();
        END
        CASE 2:
            instruction();
        END
    END
END

PROCESS control()
PRIVATE
texte[9];
BEGIN

    if(level>7 or vie<0)
        if(vie<0)
            mort=TRUE;
            vie=0;
        end
        if(vie>=0 and level>7)
        level--;
        end
        if(point>record)
            record=point;
        end
        save("jack.dat",&record,sizeof(record));
        let_me_alone();
        TIMER[1]=0;
           fade_on();
           delete_text(all_text);
           fond=load_map("progs\jack\fin_nive.map");
           put_screen(0,fond);
           write(fonte1,175,310,6,"GAME OVER");
       repeat
            frame;
       until(TIMER[1]>300)
        fade(0,0,0,2);
        while(fading);
            frame;
        end
        unload_map(fond);
        delete_text(all_text);
        let_me_alone();
        credit();
    end
    if(mort==FALSE)
    TIMER[0]=0;
    let_me_alone();
    delete_text(all_text);
    clear_screen();
    fade_on();
    repeat
        write(fonte1,180,250,6,"LEVEL :");
        write_INT(fonte1,390,253,6,&level);
        frame;
    until(TIMER[0]>300)
    fade(0,0,0,2);
    while(fading);
      frame;
    end
    end
    delete_text(all_text);
    signal(type robot, s_kill);
    signal(type bonus,s_kill);
    signal(type bonus_vie,s_kill);
    signal(type ballon,s_kill);
    stop_sound(c_ballon);
    signal(type texte_bonus,s_kill);
    fade_on();
        SWITCH(level)
        CASE 1:
            fond=load_map("progs\jack\fond1.map");
            put_screen(0,fond);
            unload_map(fond);
            texte[0]=write(fonte2,500,325,6,"Record : ");
            texte[2]=write_int(fonte3,500,370,6,&record);
            texte[3]=write(fonte2,500,418,6,"Bomb Jack");
            texte[4]=write(fonte2,540,438,6,"2000");
            texte[5]=write(fonte2,500,155,6,"Score : ");
            texte[6]=write_int(fonte3,500,200,6,&point);
            texte[7]=write(fonte2,500,265,6,"Vie : ");
            texte[8]=write_int(fonte3,568,271,6,&vie);
            texte[9]=write(0,498,465,6,"Copyright BIMWARE 1999");
            put(0,23,564,57);
            TIMER[0]=0;
            texte[1]=write(fonte1,100,280,6,"GET READY !!!");
            repeat
                frame;
            until(TIMER[0]>300)
            delete_text(texte[1]);
            if(mort==fALSE)

            FOR(y=70; y<460; y+=50)
                compteur_bombe++;
                bombe(30,y,compteur_bombe);
            END

            FOR(x=80; x<450; x+=50)
                compteur_bombe++;
                bombe(x,20,compteur_bombe);
            END

            FOR(y=250; y<450; y+=50)
                compteur_bombe++;
                bombe(430,y,compteur_bombe);
            END

            FOR(y=250; y<450; y+=50)
                compteur_bombe++;
                bombe(350,y,compteur_bombe);
            END
            end
            robot(110,50,80,150,1);
            id_jack=jack(240,200);
            mort=FALSE;

            frame;
        END
        CASE 2:
            fond=load_map("progs\jack\fond2.map");
            put_screen(0,fond);
            unload_map(fond);

            texte[0]=write(fonte2,500,325,6,"Record : ");
            texte[2]=write_int(fonte3,500,370,6,&record);
            texte[3]=write(fonte2,500,418,6,"Bomb Jack");
            texte[4]=write(fonte2,540,438,6,"2000");
            texte[5]=write(fonte2,500,155,6,"Score : ");
            texte[6]=write_int(fonte3,500,200,6,&point);
            texte[7]=write(fonte2,500,265,6,"Vie : ");
            texte[8]=write_int(fonte3,568,271,6,&vie);
            texte[9]=write(0,498,465,6,"Copyright BIMWARE 1999");
            put(0,23,564,57);
            TIMER[0]=0;
            texte[1]=write(fonte1,100,280,6,"GET READY !!!");
            repeat
                frame;
            until(TIMER[0]>300)
            delete_text(texte[1]);
            if(mort==fALSE)

            FOR(x=300; x<450; x+=50)
                compteur_bombe++;
                bombe(x,410,compteur_bombe);
            END

            FOR(x=70; x<220; x+=50)
                compteur_bombe++;
                bombe(x,410,compteur_bombe);
            END

            FOR(y=330; y>200; y-=50)
                compteur_bombe++;
                bombe(30,y,compteur_bombe);
            END

            FOR(y=330; y>200; y-=50)
                compteur_bombe++;
                bombe(450,y,compteur_bombe);
            END

            FOR(x=450; x>300; x-=50)
                compteur_bombe++;
                bombe(x,30,compteur_bombe);
            END

            FOR(x=70; x<220; x+=50)
                compteur_bombe++;
                bombe(x,30,compteur_bombe);
            END

            FOR(y=230; y>100; y-=50)
                compteur_bombe++;
                bombe(280,y,compteur_bombe);
            END

            FOR(y=130; y<280; y+=50)
                compteur_bombe++;
                bombe(200,y,compteur_bombe);
            END
            end
            robot(110,50,80,150,1);
            id_jack=jack(240,200);
            mort=FALSE;

            frame;

        end
        CASE 3:
            fond=load_map("progs\jack\fond3.map");
            put_screen(0,fond);
            unload_map(fond);

            texte[0]=write(fonte2,500,325,6,"Record : ");
            texte[2]=write_int(fonte3,500,370,6,&record);
            texte[3]=write(fonte2,500,418,6,"Bomb Jack");
            texte[4]=write(fonte2,540,438,6,"2000");
            texte[5]=write(fonte2,500,155,6,"Score : ");
            texte[6]=write_int(fonte3,500,200,6,&point);
            texte[7]=write(fonte2,500,265,6,"Vie : ");
            texte[8]=write_int(fonte3,568,271,6,&vie);
            texte[9]=write(0,498,465,6,"Copyright BIMWARE 1999");
            put(0,23,564,57);
            TIMER[0]=0;
            texte[1]=write(fonte1,100,280,6,"GET READY !!!");
            repeat
                frame;
            until(TIMER[0]>300)
            delete_text(texte[1]);
            if(mort==fALSE)

            FOR(x=200; x<350; x+=50)
                compteur_bombe++;
                bombe(x,350,compteur_bombe);
            END
            FOR(x=200; x<350; x+=50)
                compteur_bombe++;
                bombe(x,420,compteur_bombe);
            END

            FOR(x=70; x<220; x+=50)
                compteur_bombe++;
                bombe(x,200,compteur_bombe);
            END

            FOR(x=410; x>260; x-=50)
                compteur_bombe++;
                bombe(x,200,compteur_bombe);
            END

            FOR(x=410; x>260; x-=50)
                compteur_bombe++;
                bombe(x,30,compteur_bombe);
            END

            FOR(x=70; x<220; x+=50)
                compteur_bombe++;
                bombe(x,30,compteur_bombe);
            END

            FOR(y=285; y>155; y-=50)
                compteur_bombe++;
                bombe(265,y,compteur_bombe);
            END

            FOR(y=185; y<335; y+=50)
                compteur_bombe++;
                bombe(210,y,compteur_bombe);
            END
            end
            robot(110,50,80,150,1);
            id_jack=jack(240,200);
            mort=FALSE;

            frame;

        end
        CASE 4:
            fond=load_map("progs\jack\fond4.map");
            put_screen(0,fond);
            unload_map(fond);

            texte[0]=write(fonte2,500,325,6,"Record : ");
            texte[2]=write_int(fonte3,500,370,6,&record);
            texte[3]=write(fonte2,500,418,6,"Bomb Jack");
            texte[4]=write(fonte2,540,438,6,"2000");
            texte[5]=write(fonte2,500,155,6,"Score : ");
            texte[6]=write_int(fonte3,500,200,6,&point);
            texte[7]=write(fonte2,500,265,6,"Vie : ");
            texte[8]=write_int(fonte3,568,271,6,&vie);
            texte[9]=write(0,498,465,6,"Copyright BIMWARE 1999");
            put(0,23,564,57);
            TIMER[0]=0;
            texte[1]=write(fonte1,100,280,6,"GET READY !!!");
            repeat
                frame;
            until(TIMER[0]>300)
            delete_text(texte[1]);
            if(mort==fALSE)

            FOR(x=200; x>50; x-=50)
                compteur_bombe++;
                bombe(x,320,compteur_bombe);
            END

            FOR(x=370; x>240; x-=50)
                compteur_bombe++;
                bombe(x,320,compteur_bombe);
            END

            FOR(x=180; x>30; x-=50)
                compteur_bombe++;
                bombe(x,230,compteur_bombe);
            END

            FOR(x=380; x>250; x-=50)
                compteur_bombe++;
                bombe(x,230,compteur_bombe);
            END

            FOR(x=150; x>0; x-=50)
                compteur_bombe++;
                bombe(x,140,compteur_bombe);
            END

            FOR(x=380; x>250; x-=50)
                compteur_bombe++;
                bombe(x,140,compteur_bombe);
            END

            FOR(x=410; x>280; x-=50)
                compteur_bombe++;
                bombe(x,30,compteur_bombe);
            END

            FOR(x=60; x<210; x+=50)
                compteur_bombe++;
                bombe(x,30,compteur_bombe);
            END
            end
            robot(110,50,80,150,1);
            id_jack=jack(240,200);
            mort=FALSE;

            frame;


        END
        CASE 5:
            fond=load_map("progs\jack\fond5.map");
            put_screen(0,fond);
            unload_map(fond);

            texte[0]=write(fonte2,500,325,6,"Record : ");
            texte[2]=write_int(fonte3,500,370,6,&record);
            texte[3]=write(fonte2,500,418,6,"Bomb Jack");
            texte[4]=write(fonte2,540,438,6,"2000");
            texte[5]=write(fonte2,500,155,6,"Score : ");
            texte[6]=write_int(fonte3,500,200,6,&point);
            texte[7]=write(fonte2,500,265,6,"Vie : ");
            texte[8]=write_int(fonte3,568,271,6,&vie);
            texte[9]=write(0,498,465,6,"Copyright BIMWARE 1999");
            put(0,23,564,57);
            TIMER[0]=0;
            texte[1]=write(fonte1,100,280,6,"GET READY !!!");
            repeat
                frame;
            until(TIMER[0]>300)
            delete_text(texte[1]);
            if(mort==fALSE)
            FOR(y=290; y>10; y-=50)
                compteur_bombe++;
                bombe(400,y,compteur_bombe);
            END

            FOR(y=40; y<320; y+=50)
                compteur_bombe++;
                bombe(300,y,compteur_bombe);
            END

            FOR(y=290; y>10; y-=50)
                compteur_bombe++;
                bombe(150,y,compteur_bombe);
            END

            FOR(y=40; y<320; y+=50)
                compteur_bombe++;
                bombe(50,y,compteur_bombe);
            END

            end
            robot(110,50,80,150,1);
            id_jack=jack(240,200);
            mort=FALSE;

            frame;

        end
        CASE 6:

            fond=load_map("progs\jack\fond6.map");
            put_screen(0,fond);
            unload_map(fond);

            texte[0]=write(fonte2,500,325,6,"Record : ");
            texte[2]=write_int(fonte3,500,370,6,&record);
            texte[3]=write(fonte2,500,418,6,"Bomb Jack");
            texte[4]=write(fonte2,540,438,6,"2000");
            texte[5]=write(fonte2,500,155,6,"Score : ");
            texte[6]=write_int(fonte3,500,200,6,&point);
            texte[7]=write(fonte2,500,265,6,"Vie : ");
            texte[8]=write_int(fonte3,568,271,6,&vie);
            texte[9]=write(0,498,465,6,"Copyright BIMWARE 1999");
            put(0,23,564,57);
            TIMER[0]=0;
            texte[1]=write(fonte1,100,280,6,"GET READY !!!");
            repeat
                frame;
            until(TIMER[0]>300)
            delete_text(texte[1]);
            if(mort==fALSE)

            FOR(y=250; y<400; y+=50)
                compteur_bombe++;
                bombe(80,y,compteur_bombe);
            END
            FOR(y=250; y<400; y+=50)
                compteur_bombe++;
                bombe(160,y,compteur_bombe);
            END
            FOR(x=70; x<220; x+=50)
                compteur_bombe++;
                bombe(x,30,compteur_bombe);
            END
            FOR(x=370; x<520; x+=50)
                compteur_bombe++;
                bombe(x,30,compteur_bombe);
            END
            FOR(x=370; x<520; x+=50)
                compteur_bombe++;
                bombe(x,180,compteur_bombe);
            END
            FOR(x=190; x<340; x+=50)
                compteur_bombe++;
                bombe(x,390,compteur_bombe);
            END

            FOR(x=400; x>250; x-=50)
                compteur_bombe++;
                bombe(x,320,compteur_bombe);
            END
            FOR(y=220; y<370; y+=50)
                compteur_bombe++;
                bombe(210,y,compteur_bombe);
            END

            end
            robot(110,50,80,150,1);
            id_jack=jack(240,200);
            mort=FALSE;

            frame;

        END
        CASE 7:

            fond=load_map("progs\jack\fond7.map");
            put_screen(0,fond);
            unload_map(fond);

            texte[0]=write(fonte2,500,325,6,"Record : ");
            texte[2]=write_int(fonte3,500,370,6,&record);
            texte[3]=write(fonte2,500,418,6,"Bomb Jack");
            texte[4]=write(fonte2,540,438,6,"2000");
            texte[5]=write(fonte2,500,155,6,"Score : ");
            texte[6]=write_int(fonte3,500,200,6,&point);
            texte[7]=write(fonte2,500,265,6,"Vie : ");
            texte[8]=write_int(fonte3,568,271,6,&vie);
            texte[9]=write(0,498,465,6,"Copyright BIMWARE 1999");
            put(0,23,564,57);
            TIMER[0]=0;
            texte[1]=write(fonte1,100,280,6,"GET READY !!!");
            repeat
                frame;
            until(TIMER[0]>300)
            delete_text(texte[1]);
            if(mort==fALSE)

            FOR(y=110; y<260; y+=50)
                compteur_bombe++;
                bombe(85,y,compteur_bombe);
            END
            FOR(y=110; y<260; y+=50)
                compteur_bombe++;
                bombe(150,y,compteur_bombe);
            END
            FOR(y=110; y<260; y+=50)
                compteur_bombe++;
                bombe(320,y,compteur_bombe);
            END
            FOR(y=110; y<260; y+=50)
                compteur_bombe++;
                bombe(385,y,compteur_bombe);
            END
            FOR(y=370; y>220; y-=50)
                compteur_bombe++;
                bombe(390,y,compteur_bombe);
            END
            FOR(y=370; y>220; y-=50)
                compteur_bombe++;
                bombe(325,y,compteur_bombe);
            END
            FOR(y=370; y>220; y-=50)
                compteur_bombe++;
                bombe(160,y,compteur_bombe);
            END
            FOR(y=370; y>220; y-=50)
                compteur_bombe++;
                bombe(90,y,compteur_bombe);
            END

            end
            robot(110,50,80,150,1);
            id_jack=jack(240,200);
            mort=FALSE;

            frame;

        END

        CASE 8:
            level++;
            control();
        end

        END
        LOOP
            if(key(_b))
                let_me_alone();
                robots=1;
                compteur_bombe=0;
                level+=6;
                control();
            end
            if(robots==0 and not destruction AND mort==FALSE)
                id_robot=robot(110,50,80,150,1);
            end
            if(rand(1,1200)<4 and compte_bonus==0)
                x=rand(10,460);
                compte_bonus++;
                bonus(x,5);
            end

            if(rand(1,3000)<3 and compte_bonus==0 and mort==false and vie<3)
                x=rand(10,460);
                compte_bonus++;
                bonus_vie(x,5);
            end
            if(rand(1,200)<2 and robots>2 and compte_ballon==0 and mort==false)
                compte_ballon++;
                x=rand(10,460);
                c_ballon=sound(s_ballon,256,256);
                ballon(450,5);
            end


            Frame;
        END
END

PROCESS jack(x,y)
private

    incx=0;
    dernier_y=0;
    derniere_vit=0;

BEGIN
GRAPH=2; size=120; priority=1;

    loop
        if(TIMER[2]>700 AND destruction==TRUE)
            stop_sound(c_alarme);
            destruction=false;
            reprise=true;
            compte_ballon=0;
        end
        if(destruction)
            col_robot=collision(type robot);
            if(col_robot)
                signal (col_robot,s_kill);
                point+=50;
                robots--;
            end
        end

        col_bombe=collision(type bombe);
        col_bonus=collision(type bonus);
        col_vie=collision(type bonus_vie);
        col_ballon=collision(type ballon);

        IF(col_ballon and mort==FALSE)
            stop_sound(c_ballon);
            signal (col_ballon, s_kill);
            reprise=false;
            destruction=true;
            TIMER[2]=0;
        end

        if(col_vie and mort==FALSE)
            compte_bonus=0;
            point+=10;
            vie++;
            signal(col_vie,s_kill);
            sound(s_vie,256,256);

        end
        if(col_bombe and mort==FALSE)
            if(col_bombe.graph==8)
                point+=5;
            end
            if(col_bombe.graph==9 or col_bombe.graph==10)
                if(bonus_fois>1)
                    texte_bonus(col_bombe.x,col_bombe.y);
                end
                point+=15*bonus_fois;
                r_b_a++;

            end
            sound(s_bombe,256,256);
            signal(col_bombe,s_kill);
            compteur_bombe--;
            if(compteur_bombe==0)
                level++;
                signal(type bombe, s_kill);
                signal(type robot, s_kill);
                signal(type bonus,s_kill);
                signal(type bonus_vie,s_kill);
                signal(type ballon,s_kill);
                signal(type texte_bonus,s_kill);

                fade(0,0,0,2);
                while(fading);
                    frame;
                end
                fin_niveau();
            end
        end
        if(col_bonus and mort==FALSE)
            point+=5;
            compte_bonus=0;
            bonus_fois++;
            sound(s_bonus,256,256);
            signal(col_bonus,s_kill);
        end

        IF ((key(_right) OR joy.right) AND vitesse<6)
            graph++;
            if(graph>7)
                graph=2;
            end
            vitesse+=1;
            flags=1;
        ELSE
            IF ((key(_left) OR joy.left) AND vitesse>-6)
                graph++;
                if(graph>7)
                    graph=2;
                end

                vitesse-=2;
                flags=0;
            ELSE
                IF (vitesse>0)
                    vitesse--;
                END
                IF (vitesse<0)
                    vitesse++;
                END
            END
        END

        derniere_vit=vitesse;
        IF (derniere_vit<>0)
            incx=derniere_vit/abs(derniere_vit);
            WHILE (derniere_vit<>0)

                IF (map_get_pixel(0,899+LEVEL,(x+incx),(y-2))<>15)

                    IF (map_get_pixel(0,899+LEVEL,(x+incx),(y-32))<>15)
                        x+=incx;
                    END
                END
                derniere_vit-=incx;
            END
        END

        IF  (key(_control) or joy.button1 and au_sol)
            sound(s_saute,56,200);
            vitesse_gravite=-force_saut;
        END
        gravite(18,18);
        frame;
     end
END


PROCESS bombe(x,y,num);
BEGIN
    graph=9;size=120;
        LOOP
        bombe_allume=max(id.num,compteur_bombe);
        if(id.num==bombe_allume)
            graph++;
            if(graph>10)
                graph=9;
            end
        else
        GRAPH=8;
        end

        frame;
    end
END

PROCESS robot(x,y,x1,x2,forme);
PRIVATE
col_jack=0;
direction=-1;
debut;
fin;
ancien_forme;
incr_y;
BEGIN
  robots++;
  TIMER[1]=0;
  TIMER[3]=0;
  LOOP
    if(reprise and id.forme==3)
        stop_sound(c_alarme);
        id.forme=ancien_forme;
        TIMER[3]=400;
    end
    If(destruction and id.forme<>3)
        ancien_forme=id.forme;
        id.forme=3;
    end
        if(robots<4 and timer[3]>700 and not(destruction))
        if(rand(0,2)<1)
             robot(110,50,80,150,1);
        else
             id_robot=robot(350,50,310,380,1);
        end
        timer[3]=0;
    end

    if(id.forme==1)
        FROM graph = 11 to 14;
            col_jack=collision (TYPE jack);
            IF (col_jack and mort==FALSE)
                sound(s_mort,256,256);
                mort=true;
                REPEAT
                    col_jack.y+=incr_y;
                    incr_y++;
                    col_jack.angle+=pi/16;
                    col_jack.size+=14;
                    FRAME;
                UNTIL (out_region(col_jack,0));
            signal (col_jack,s_kill);
            vie--;
            bonus_fois=1;
            compte_bonus=0;
            robots=0;
            control();
            END

        IF (au_sol)
            IF (direction==-1 ) x+=2; flags=1; IF (x>x2) direction=1; END
                   ELSE x-=2; flags=0; IF (x<x1) direction=-1; END
            END
            IF(TIMER[1]>=300)
            x2+=50;
            END
            if(y>410)
                sound(s_trans,256,256);
                from graph=56 to 61;
                    FRAME;
                end
                id.forme=2;
                TIMER[1]=0;
            end
        END
        gravite_robot(15,14);
        FRAME;
        end
      end
        IF(id.forme==2)
            debut=15;
            fin=22;
            for(graph=debut; graph<=fin; graph++)
                col_jack=collision (TYPE jack);
                IF (col_jack AND mort==FALSE)
                    sound(s_mort,256,256);
                    mort=true;
                    REPEAT
                        col_jack.y+=incr_y;
                        incr_y++;
                        col_jack.angle+=pi/16;
                        col_jack.size+=14;
                        FRAME;
                    UNTIL (out_region(col_jack,0));
                    signal (col_jack,s_kill);
                    vie--;
                    bonus_fois=1;
                    compte_bonus=0;
                    robots=0;
                    control();
                END

                IF (x>id_jack.x)
                    flags=0;
                    if(map_get_pixel(0,899+level,x+16,y)==20 or map_get_pixel(0,899+level,x-16,y)==20)
                            y+=3;
                    else
                        if(map_get_pixel(0,899+level,x+16,y)==15 or map_get_pixel(0,899+level,x-16,y)==15)
                            y-=3;
                        else
                            x-=1;
                        end

                    end

                else
                    flags=1;
                    if(map_get_pixel(0,899+level,x+16,y)==20 or map_get_pixel(0,899+level,x-16,y)==20)
                            y+=3;
                    else
                        if(map_get_pixel(0,899+level,x+16,y)==15 or map_get_pixel(0,899+level,x-16,y)==15)
                            y-=3;
                        else
                            x+=1;
                        end

                    end

                end

                IF (y<id_jack.y)
                    if(map_get_pixel(0,899+level,x,y+16)<>61)
                        y++;
                    else
                        flags=1;
                        x+=2;
                    end
                else
                    if(map_get_pixel(0,899+level,x,y-19)<>115)
                        y--;
                    else
                        flags=0;
                        x-=2;
                    end
                end
                frame;

            END
          END
            if(id.forme==3)
                if(TIMER[2]>700)
                    stop_sound(c_alarme);
                end
                graph=40;
                if(TIMER[2]>400)
                    c_alarme=sound(s_alarme,256,256);
                 loop
                    if(reprise)
                        break;
                    end
                    GRAPH++;
                    if(graph>=48)
                        graph=40;
                    end
                    FRAME;
                 end
                end
            frame;
            END
  END

END

PROCESS bonus(x,y)
BEGIN
    REPEAT
        from graph=24 to 31;
            y+=2;
            Frame;
        end
        graph=24;
    UNTIL(out_region(id,0));
    compte_bonus=0;
END

PROCESS bonus_vie(x,y)
BEGIN
    REPEAT
        from graph=32 to 39;
            y+=2;
            Frame;
        end
        graph=32;
    UNTIL(out_region(id,0));
    compte_bonus=0;
END

PROCESS ballon(x,y)
PRIVATE
incr_x=4;
BEGIN
graph=49;
    REPEAT
        graph++;
        if(graph>55)
            graph=49;
        end
        if(x<10 or x>460)
            incr_x=-incr_x;
        end
        y++;
        x=x+incr_x;
        frame;
    UNTIL(out_region(id,0));
    stop_sound(c_ballon);
    compte_ballon=0;
END

PROCESS texte_bonus(x,y)
PRIVATE
texte1;
texte2;
coord_y;
BEGIN
    texte1=write(fonte4,x,y,0,"X ");
    texte2=write_int(fonte4,x+12,y,0,&bonus_fois);
    coord_y=y;
    repeat

        if(coord_y>30)
            y-=5;
        else
            y+=5;
        end

        move_text(texte1,x,y);
        move_text(texte2,x+10,y);
        frame;

    until(y<0)

    delete_text(texte1);
    delete_text(texte2);

END

PROCESS fin_niveau();
PRIVATE
map_fin;
bonus_point=0;
BEGIN
    SWITCH(r_b_a)
    CASE 24:
        bonus_point=1000;
    END
    CASE 23:
        bonus_point=700;
    END
    CASE 22:
        bonus_point=500;
    END
    CASE 21:
        bonus_point=300;
    END
    END

    point=point+bonus_point;
    fade_on();
    let_me_alone();
    delete_text(all_text);
    clear_screen();
    map_fin=load_map("progs\jack\fin_nive.map");
    put_screen(0,map_fin);
    IF(r_b_a>20)
    REPEAT
        write(fonte2,90,250,0,"tu as ramasse :");
        write_int(fonte3,307,245,0,&r_b_a);
        write(fonte2,360,250,0,"bombes allumees");
        write(fonte2,90,300,0,"tu gagnes un bonus de :");
        write_int(fonte3,405,294,0,&bonus_point);
        write(fonte2,480,302,0,"points");
        write(0,180,440,0,"APPUIE SUR LA TOUCHE ESPACE POUR CONTINUER...");
        frame;
    until(key(_space))
    ELSE
    REPEAT
        write(fonte2,135,250,0,"desole tu n'as ramasse que");
        write_int(fonte3,300,277,0,&r_b_a);
        write(fonte2,200,320,0,"bombes allumees");
        write(fonte2,140,370,0,"Donc tu n'as pas de bonus");
        write(0,180,440,0,"APPUIE SUR LA TOUCHE ESPACE POUR CONTINUER...");
        frame;
    until(key(_space))
    end
    fade(0,0,0,2);
    while(fading);
        frame;
    end
    robots=0;
    r_b_a=0;
    bonus_fois=1;
    destruction=FALSE;
    reprise=FALSE;
    control();
END

PROCESS gravite(offset_sup, offset_inf);

PRIVATE
    c_sol=53;
    c_toit=33;
    gravite_temp;
    c_mur=15;

BEGIN
    father.au_sol=FALSE;
    gravite_temp=(father.vitesse_gravite+=2);
    IF (gravite_temp>15)
        father.vitesse_gravite=15;
        gravite_temp=15;
    END

    IF (gravite_temp<0)

    WHILE (gravite_temp++!=0)

    IF(key(_alt) or joy.button2 and not father.au_sol)
        father.vitesse_gravite=0;
        break;
    end
    IF (map_get_pixel(0,899+level,father.x,(father.y-offset_sup))<>c_toit)
        father.y--;
    ELSE
        father.vitesse_gravite=0;
        BREAK;
    END

    END

    ELSE

        if(key(_control) and map_get_pixel(0,899+level,father.x,(father.y-offset_sup))<>c_toit)
          id_jack.y-=5;
        end
        father.y+=gravite_temp;

   FROM gravite_temp=-15 TO 8 ;

   IF (map_get_pixel(0,899+level,father.x,(father.y+gravite_temp+offset_inf))==c_sol)
        father.au_sol=TRUE;
        BREAK;
   END
   END

   IF (gravite_temp<9)
        father.y+=gravite_temp;
        father.vitesse_gravite=0;
   END
   END


END


PROCESS gravite_robot(offset_sup, offset_inf);

PRIVATE
    c_sol=53;
    c_toit=33;
    gravite_temp;

BEGIN

    father.au_sol=FALSE;
    gravite_temp=(father.vitesse_gravite+=2);
    IF (gravite_temp>15)
        father.vitesse_gravite=15;
        gravite_temp=15;
    END

    IF (gravite_temp<0)

    WHILE (gravite_temp++!=0)

    IF (map_get_pixel(0,899+level,father.x,(father.y-offset_sup))<>c_toit)
        father.y--;
    ELSE
        father.vitesse_gravite=0;
        BREAK;
    END

    END

    ELSE

    father.y+=gravite_temp;

   FROM gravite_temp=-15 TO 8;

   IF (map_get_pixel(0,899+level,father.x,(father.y+gravite_temp+offset_inf))==c_sol)
        father.au_sol=TRUE;
        BREAK;
   END
   END

   IF (gravite_temp<9)
        father.y+=gravite_temp;
        father.vitesse_gravite=0;
   END
   END

END
PROCESS max(a,b)
BEGIN
    IF(a>b)
        RETURN(a);
    ELSE
        RETURN(b);
    END
END
PROCESS instruction()
PRIVATE
BEGIN

  CLEAR_SCREEN();
  fond=load_map("progs\jack\fin_nive.map");
  fade_on();
  put_screen(0,fond);
  unload_map(fond);

  write(0,85,232,0,"Bombe éteinte  5 points");
  write(0,85,272,0,"Bombe allumée 15 points");
  write(0,85,310,0,"Bonus multiplicateur  5 points");
  write(0,335,310,0,"Vie supplémentaire 10 points");
  write(0,355,232,0,"Transforme les robots en soleil");
  write(0,355,272,0,"Robots vulnérables  50 points");

  write(0,40,375,6,"Jack se contrôle avec les touches du curseur, pour sauter appuyez sur la touche CTRL et pour");
  write(0,40,395,6,"couper son élan appuyer sur la touche ALT. Essayez de rammasser le maximum de bombes allumées");
  write(0,40,415,6,"pour obtenir des points bonus.");
  write(0,190,440,0,"APPUIE SUR UNE TOUCHE POUR CONTINUER...");

  while(SCAN_CODE==0);

        xput(0,8,60,230,0,120,0,0);
        xput(0,10,60,270,0,120,0,0);
        xput(0,24,60,310,0,100,0,0);
        xput(0,32,310,310,0,100,0,0);
        xput(0,49,310,230,0,100,0,0);
        xput(0,40,310,270,0,100,0,0);

        frame;
  end

  fade(200,0,0,6);
  WHILE(fading)
    frame;
  end
  delete_text(all_text);
  CLEAR_SCREEN();
  menu();
END

PROCESS credit()
PRIVATE
image;
musique;
BEGIN
let_me_alone();
clear_screen();
load_pal("progs\jack\palette.pal");
musique=load_song("progs\jack\emelie.xm",1);
image=load_map("progs\jack\credit.map");
fade_on();
put_screen(0,image);
song(musique);
while(SCAN_CODE==0);
     delete_text(all_text);
     put_screen(0,image);
     Frame;
end

  fade(0,0,0,2);
  WHILE(fading)
    frame;
  end
  CLEAR_SCREEN();
  exit("Tchao",0);
END